Старье от Шаоса

Старый спектрумистский форум

Moderator: Shaos

User avatar
Shaos
Admin
Posts: 24055
Joined: 08 Jan 2003 23:22
Location: Silicon Valley

Post by Shaos »

Shaos wrote: В апреле 1993 после нескольких экспериментов я создал программу ZVUK-2,
которую можно найти в файле _zvuk2.tap. Программа позволяла записывать
в память компьютера звук и музыку с магнитофонного входа, воспроизводить
ее там же, а также совершать над сохраненным звуком некоторые действия,
как например блочное копирование и т.д. В программе использовался
русский шрифт, сделанный по рецепту из какой-то спектрумистской книжки
того времени, названия которой я уже не помню:

Image

В файле _z_demo1.tap содержится кодовый блок, записанный этой
программой в те далекие времена, который показывает что можно
было cделать со звуком путем блочных перемещений. Отличительной
особенностью программы ZVUK-2 является то, что кодовый блок ответственный
за запись и воспроизведение звука (кстати набранный с помощью всё
того же hexloadera) был встроен непосредственно в бейсик-код.

Code: Select all

    0 GO TO 9999: REM ZVUK-2 Ekaterinburg  8.4.1993   Shabarshin A.   UPI             NOT PIRATING! 
   80 DATA "b",0,126,64,124,66,66,124,0
   81 DATA "g",0,126,64,64,64,64,64,0
   82 DATA "d",0,28,36,36,36,36,126,66
   83 DATA "j",0,65,73,62,73,73,65,0
   84 DATA "i",0,66,70,74,82,98,66,0
   85 DATA "l",0,30,34,34,34,34,98,0
   86 DATA "p",0,126,66,66,66,66,66,0
   87 DATA "o",0,66,66,36,24,16,96,0
   88 DATA "c",0,68,68,68,68,68,126,2
   89 DATA "h",0,66,66,66,126,2,2,0
   90 DATA "n",0,65,73,73,73,73,127,0
   91 DATA "m",0,65,73,73,73,73,127,1
   92 DATA "e",0,60,66,30,2,66,60,0
   93 DATA "u",0,76,82,114,82,82,76,0
   94 DATA "a",0,62,66,66,62,34,66,0
   95 DATA "s",24,66,70,74,82,98,66,0
   96 DATA "r",0,64,64,124,66,66,124,0
   97 DATA "t",0,192,64,124,66,66,124,0
   98 DATA "f",0,127,73,73,73,127,8,0
   99 DATA "q",0,66,66,114,74,74,114,0
  100 GO SUB 8000
  110 GO SUB 7000
  120 INPUT I: GO TO 2000+I*500
 2000 INPUT "CMEH\iT\r A\dPEC C\h\iT\qBAH\i\a ?";A$: IF A$="y" THEN INPUT ADL: GO TO 2020
 2010 LET ADL=ADR
 2020 PRINT AT 21,0;: LOAD ""CODE ADL: GO TO 100
 2500 INPUT "A\dPEC:";ADR: GO TO 110
 3000 INPUT "\d\l\iHA:";LEN: GO TO 110
 3500 INPUT "3A\dEP\jKA:";TM: GO TO 110
 4000 INPUT "KO\l-BO \pOBTOPEH\i\s:";QNT: PRINT AT 6,25;"  "
 4010 PRINT AT 6,25; FLASH 1;QNT: GO TO 110
 4500 PRINT AT 21,0; FLASH 1;"3A\p\iC\r B \pAM\aT\r": RANDOMIZE USR 27000: GO TO 100
 5000 PRINT AT 21,0; FLASH 1;"BOC\pPO\i3BE\dEH\iE \i3 \pAM\aT\i": FOR I=1 TO QNT: RANDOMIZE USR 27093: NEXT I: GO TO 100
 5500 INPUT "K\o\dA \pEPEME\mAT\r ?";AEN: IF AEN<ADR+LEN AND AEN>=ADR THEN GO TO 5590
 5510 IF AEN+LEN>AMAX THEN GO TO 5590
 5511 LET A1=ADR: IF A1>AEN THEN LET A1=A1+LEN
 5512 LET A2=LEN: LET A3=AEN: LET ADR=AMAX-LEN: LET LEN=ADR-AEN: LET AEN=AMAX: GO SUB 7030: POKE 27118,136: RANDOMIZE USR 27110: POKE 27118,176
 5520 LET LEN=A2
 5530 LET ADR=A1: LET AEN=A3: GO SUB 7000: RANDOMIZE USR 27110: GO TO 110
 5590 PRINT AT 21,0; FLASH 1;"O\n\i\bKA": BEEP 1,1: GO SUB 8000: GO TO 120
 6000 INPUT "CT\iPAT\r ?";A$: IF A$<>"y" THEN GO TO 110
 6010 LET A1=ADR: LET A2=LEN: LET AEN=ADR: LET ADR=ADR+LEN: LET LEN=AMAX-ADR: GO SUB 7000: RANDOMIZE USR 27110
 6020 LET ADR=AEN+LEN: LET LEN=AMAX-ADR: GO SUB 7000: RANDOMIZE USR 27121: LET ADR=A1: LET A2=LEN: GO SUB 7000: GO TO 110
 6500 INPUT "\iM\a:";A$: IF A$="" THEN GO TO 110
 6510 PRINT AT 21,0;: SAVE A$CODE ADR,LEN: GO TO 100
 7000 IF ADR+LEN>AMAX THEN GO TO 5590
 7003 LET A$="": FOR I=1 TO 5: LET A$=A$+CHR$ 8: NEXT I: LET B$="     ": IF ADR>=AMIN AND ADR<=AMAX THEN  PRINT AT 3,26;B$;A$; FLASH 1;ADR: GO TO 7010
 7005 GO TO 5590
 7010 IF ADR+LEN<=AMAX THEN  PRINT AT 4,15;B$;A$; FLASH 1;LEN: GO TO 7020
 7015 GO TO 5590
 7016 REM NOT STEP ix FOR To\Y FLASH RETURN NEW @\SCHR$ \^iWCHR$ \Viw#xATN CHR$ \RiyATN CHR$ \Ri<>~W NEW OPEN # RETURN zCHR$ LN iCHR$ POINT i#xATN CHR$ INKEY$iyATN CHR$ INKEY$i<> STEP INVERSE i STEP \Ri CLS <> STEP INVERSE i STEP INKEY$i CLS <>*{i GO SUB K\*i NEXT <> STEP INVERSE i GO SUB [}i GO SUB VAL CLS <> STEP INVERSE i6#xLEN CHR$ POKE i CLS <>2
 7020 PRINT AT 5,20;B$;A$; FLASH 1;TM
 7030 RANDOMIZE ADR: POKE 27003,PEEK 23670: POKE 27004,PEEK 23671
 6971 RANDOMIZE AEN: POKE 27005,PEEK 23670: POKE 27006,PEEK 23671
 7040 RANDOMIZE LEN: POKE 27007,PEEK 23670: POKE 27008,PEEK 23671
 7050 POKE 27020,TM: POKE 27063,TM: RETURN
 8000 CLS : PRINT AT 0,0; INK 4;"ZVUK-2"; INK 7;"  \nA\bAP\n\iH A   "; INK 6;" 2.04.1993"
 8005 LET B$=" \b\lOKA "
 8010 PRINT "________________________________"
 8020 PRINT : PRINT "1.HA\hA\l\rH\q\s A\dPEC";B$;"  "; FLASH 1;ADR
 8030 PRINT "2.\d\l\iHA";B$;" "; FLASH 1;LEN; FLASH 0;" \bA\sT"
 8040 PRINT "3.3A\dEP\jKA(1..40)   "; FLASH 1;TM
 8050 PRINT "4.KO\l\i\hECTBO \pOBTOPEH\i\s  "; FLASH 1;QNT
 8060 PRINT "5.3A\p\iC\r";B$
 8070 PRINT "6.BOC\pPO\i3BE\dEH\iE";B$: PRINT "7.KO\p\iPOBAH\iE";B$;"C PA3\dB\i\jKO\s": PRINT "8.CT\iPAH\iE";B$: PRINT "9.B\q\gP\o3KA";B$;"HA MA\gH\iTO\fOH": PRINT "0.3A\gP\o3KA";B$;"C MA\gH\iTO\fOHA"
 8080 PRINT : PRINT "M\iH\iMA\l\rH\q\s A\dPEC    "; PAPER 6; INK 0;AMIN
 8090 PRINT "MAKC\iMA\l\rH\q\s A\dPEC   "; PAPER 6; INK 0;AMAX
 8100 PRINT "MAKC\iMA\l\rHA\a \d\l\iHA   "; PAPER 6; INK 0;LMAX
 9000 RETURN
 9010 INPUT INP: FOR I=INP TO 4E10: PRINT I,PEEK I;TAB 22;CHR$ (PEEK I*(PEEK I>=32)): NEXT I
 9015 LET err=256*PEEK 23614+PEEK 23613: POKE err+1,0: BORDER 0: PAPER 0: INK 6: CLS : PRINT "ZVUK-2.EKATERINBURG"
 9017 RESTORE 80: FOR z=1 TO 20: READ a$: FOR x=0 TO 7: READ y: POKE USR a$+x,y: NEXT x: NEXT z
 9020 LET AMIN=28800: LET AMAX=65280: LET ADR=AMIN: LET LMAX=AMAX-AMIN: LET LEN=LMAX: LET AEN=40000: LET TM=20: LET QNT=1: RETURN
 9999 GO SUB 9015: GO TO 100
Я тут за главного - если что шлите мыло на me собака shaos точка net
Top
User avatar
Shaos
Admin
Posts: 24055
Joined: 08 Jan 2003 23:22
Location: Silicon Valley

Post by Shaos »

Shaos wrote:Еще в продолжении темы - вот простейшая бейсик программа, которую я написал за 15 минут чтобы обеспечить цветовое сопровождение студенческой вечеринки в 1993 году: 1993show.zip (476 bytes):

Image

Code: Select all

   10 BORDER 0: PAPER 0: INK 7: CLS 
   20 LET x=0: LET y=0
   30 FOR i=1 TO 50
   40 LET x1=255-x: LET y1=175-y
   45 LET dx=64-INT (128*RND): IF (x+dx>128) OR (x+dx<0) THEN GO TO 45
   46 LET dy=44-INT (88*RND): IF (y+dy>128) OR (y+dy<0) THEN GO TO 46
   47 INK (INT (7*RND)+1)
   50 PLOT x,y: DRAW dx,dy
   60 PLOT x1,y: DRAW -dx,dy
   70 PLOT x1,y1: DRAW -dx,-dy
   80 PLOT x,y1: DRAW dx,-dy
   90 LET x=x+dx: LET y=y+dy: NEXT i: GO TO 10
Я тут за главного - если что шлите мыло на me собака shaos точка net
Top
User avatar
Shaos
Admin
Posts: 24055
Joined: 08 Jan 2003 23:22
Location: Silicon Valley

Post by Shaos »

Shaos wrote:Вторая волна моего увлечения спектрумом пришлась на 1996-1997 годы - когда у меня дома еще не было PC, а чего-то программировать сильно хотелось. Вот небольшой плод моего творчества того времени - говорящая программа для изучения английского языка: 1996engl.zip (3.6K):

Image

Программа написана на бейсике c русификатором (таким же как и в ZVUK-2) и в ней использовался кодовый блок - говорилка размером меньше килобайта, выдранная мной еще в 1993 году из какой-то восточно-европейской говорящей программы. Английские слова в исполнении этой говорилки звучали вот так: english.mp3 (135K).

Code: Select all

    5 REM SHABARSHIN A. 1996
   10 LET n=30: INK 4: PRINT "\*1996 <ENGLISH-1> SHABARSHIN A.","-------- PLEASE ! WAIT --------"
   15 FOR z=1 TO 20
   20 READ a$
   30 FOR x=0 TO 7
   40 READ y
   50 POKE USR a$+x,y
   60 NEXT x
   70 NEXT z
   80 DATA "b",0,126,64,124,66,66,124,0
   81 DATA "g",0,126,64,64,64,64,64,0
   82 DATA "d",0,28,36,36,36,36,126,66
   83 DATA "j",0,65,73,62,73,73,65,0
   84 DATA "i",0,66,70,74,82,98,66,0
   85 DATA "l",0,30,34,34,34,34,98,0
   86 DATA "p",0,126,66,66,66,66,66,0
   87 DATA "o",0,66,66,36,24,16,96,0
   88 DATA "c",0,68,68,68,68,68,126,2
   89 DATA "h",0,66,66,66,126,2,2,0
   90 DATA "n",0,65,73,73,73,73,127,0
   91 DATA "m",0,65,73,73,73,73,127,1
   92 DATA "e",0,60,66,30,2,66,60,0
   93 DATA "u",0,76,82,114,82,82,76,0
   94 DATA "a",0,62,66,66,62,34,66,0
   95 DATA "s",24,66,70,74,82,98,66,0
   96 DATA "r",0,64,64,124,66,66,124,0
   97 DATA "t",0,192,64,124,66,66,124,0
   98 DATA "f",0,127,73,73,73,127,8,0
   99 DATA "q",0,66,66,114,74,74,114,0
  100 POKE 23658,8: LET LL=12: DIM e$(n,LL): DIM r$(n,LL): DIM t$(n,LL): DIM q(n): DIM C$(2,LL)
  105 LET P$="PRAAVILNO": LET V$="WEERNO"
  110 RESTORE 5001: FOR i=1 TO n: READ r$(i),e$(i),t$(i): LET Q(I)=0: NEXT i
  115 FOR I=1 TO 10: BEEP 0.03,I: NEXT I
  120 CLS : RANDOMIZE : LET XX=RND
  125 PRINT AT 0,0;"\*1996 <ENGLISH-1>  \nA\bAP\n\iH A.","================================"
  130 PRINT "1. \pPO\i3HECT\i BCE C\lOBA"
  140 PRINT "2. TECT HA C\l\oX"
  150 PRINT "3. TECT HA \pEPEBO\d C P\oCCKO\gO"
  160 PRINT "4. TECT HA \pEPEBO\d C AH\g\l\i\sCKO\gO"
  170 PRINT "5. 3A\p\iC\r \pPO\gPAMM\q HA MA\g."
  200 INPUT "BA\n B\q\bOP:";MO
  210 IF MO=1 THEN GO SUB 1100
  220 IF MO=2 THEN GO SUB 2000
  230 IF MO=3 THEN GO SUB 3000
  240 IF MO=4 THEN GO SUB 4000
  250 IF MO=5 THEN GO SUB 9000
  290 IF MO=11 THEN GO SUB 1000
  299 GO TO 120
  999 STOP 
 1000 INPUT A$: GO SUB 7000: RETURN 
 1100 CLS : FOR J=1 TO N: LET a$=t$(J)
 1110 PRINT J;" ";E$(J),Q(J)
 1120 GO SUB 7000
 1140 NEXT J: RETURN 
 1200 CLS : FOR I=1 TO N: LET Q(I)=0: NEXT I: RETURN 
 1300 LET XA=11*XX+PI: LET XX=XA-INT XA: LET R=INT (XX*N)+1
 1310 IF Q(R)>2 THEN GO TO 1300
 1399 RETURN 
 1400 LET a$=t$(R): GO SUB 7000: RETURN 
 2000 GO SUB 1200
 2010 GO SUB 1300
 2020 GO SUB 1400
 2030 INPUT "BBE\d\iTE C\lOBO:";O$
 2040 IF O$=" STOP " THEN RETURN 
 2050 IF O$="?" THEN GO TO 2020
 2055 LET C$(1)=O$
 2060 IF E$(R)<>C$(1) THEN GO TO 2100
 2070 REM *** O$=E$
 2080 LET Q(R)=Q(R)+1: PRINT O$;" \pPAB\i\l\rHO!": LET A$=P$: GO SUB 7000: GO TO 2010
 2100 REM *** O$<>E$
 2110 LET Q(R)=Q(R)-1: PRINT O$;" / ";E$(R): BEEP 0.3,-19: GO TO 2010
 2999 RETURN 
 3000 GO SUB 1200
 3010 GO SUB 1300
 3020 PRINT R$(R);
 3030 INPUT "BBE\d\iTE \pEPEBO\d:";O$
 3040 IF O$=" STOP " THEN RETURN 
 3050 LET C$(1)=O$
 3060 IF C$(1)=E$(R) THEN PRINT "=";E$(R);" BEPHO!": LET A$=V$: GO SUB 7000: LET Q(R)=Q(R)+1: GO TO 3010
 3070 LET Q(R)=Q(R)-1: PRINT "=>";O$;" / ";E$(R): BEEP 0.3,-19: GO TO 3010
 3999 RETURN 
 4000 GO SUB 1200
 4010 GO SUB 1300
 4020 PRINT E$(R);: GO SUB 1400
 4030 INPUT "BBE\d\iTE \pEPEBO\d:";O$
 4040 IF O$=" STOP " THEN RETURN 
 4050 LET C$(1)=O$
 4060 IF C$(1)=R$(R) THEN PRINT "=";R$(R);" BEPHO!": LET A$=V$: GO SUB 7000: LET Q(R)=Q(R)+1: GO TO 4010
 4070 LET Q(R)=Q(R)-1: PRINT "=>";O$;" / ";R$(R): BEEP 0.3,-19: GO TO 4010
 4999 RETURN 
 5001 DATA "3A\pAC C\lOB","VOCABULARY","VEKEEB'ULERI"
 5002 DATA "CM\qC\l","MEANING","MIINING"
 5003 DATA "\dOKA3\qBAT\r","PROVE","PRUUUV"
 5004 DATA "\dO\gOBOP\iT\rC\a","AGREE UPON","EGRII EPOON"
 5005 DATA "\fAKT\i\hECK\i\s","ACTUAL","EEKT'UEL"
 5006 DATA "TO\hH\q\s","ACCURATE","EEK'URIT"
 5007 DATA "\pPOM\q\n\lEHH\q\s","COMMERCIAL","KEMEESEL"
 5008 DATA "\dAHH\qE","DATA","DEEITE"
 5009 DATA "\f\i\g\oPA","FIGURE","FIIGE"
 5010 DATA "\pP\i\bOP","INSTRUMENT","IINSTRUMENT"
 5011 DATA "C\o\mECTBEHH\q\s","MATERIAL","METIIRIEL"
 5012 DATA "\g\lABH\q\s","PRINCIPAL","PRIINSIPEL"
 5013 DATA "\pOCTE\pEHH\q\s","PROGRESSIVE","PREGREESIV"
 5014 DATA "\cE\l\r","OBJECT","OOBZIKT"
 5015 DATA "O\b\tEKT","SUBJECT","SAABZIKT"
 5016 DATA "O\hEH\r","GREATLY","GREEITLI"
 5017 DATA "\n\iPOKO","LARGELY","LAAZHLI"
 5018 DATA "E\dBA","HARDLY","HAADLI"
 5019 DATA "\pO\hT\i","NEARLY","NIIELI"
 5020 DATA "\p\lOXO","POORLY","PUUELI"
 5021 DATA "\pOKA","SO FAR","SOU FAA"
 5022 DATA "\lE\gKO","READILY","REEDILI"
 5023 DATA "\pPE\j\dE","PREVIOUSLY","PRIIV'ESLI"
 5024 DATA "\gOTOB\q\s","READY","REEDI"
 5025 DATA "P\a\dOM","BESIDE","BISAAID"
 5026 DATA "\pOM\iMO","BESIDES","BISAAIDZ"
 5027 DATA "\hEPTA","FEATURE","FIITCE"
 5028 DATA "\b\o\d\o\mEE","FUTURE","F'UUTCE"
 5029 DATA "\dA\lEE","FURTHER","FEEZHE"
 5030 DATA "HAKOHE\c","AT LAST","ET LAAST"
 7000 POKE 60211,20
 7050 LET a=61024
 7070 FOR i=1 TO LEN a$
 7080 POKE a+i-1,CODE a$(i TO i)
 7090 NEXT i: POKE a+i,0
 7095 POKE 60214,96: POKE 60215,238
 7100 RANDOMIZE USR 60000
 7110 RETURN 
 8000 CLEAR 59999: BORDER VAL "1": PAPER VAL "1": INK VAL "1": CLS : LOAD ""CODE : GO TO 10
 9000 SAVE "ENGLISH-1" LINE 8000: SAVE "ENG-SAY" CODE 60000,801
 9999 VERIFY "ENGLISH-1": VERIFY "ENG-SAY" CODE 60000,801: RETURN
Я тут за главного - если что шлите мыло на me собака shaos точка net
Top
7400
Maniac
Posts: 254
Joined: 14 Jul 2011 02:18
Location: Гомель

Post by 7400 »

Code: Select all

   80 DATA "b",0,126,64,124,66,66,124,0 
    81 DATA "g",0,126,64,64,64,64,64,0 
    82 DATA "d",0,28,36,36,36,36,126,66 
    83 DATA "j",0,65,73,62,73,73,65,0 
    84 DATA "i",0,66,70,74,82,98,66,0 
    85 DATA "l",0,30,34,34,34,34,98,0 
    86 DATA "p",0,126,66,66,66,66,66,0 
    87 DATA "o",0,66,66,36,24,16,96,0 
    88 DATA "c",0,68,68,68,68,68,126,2 
    89 DATA "h",0,66,66,66,126,2,2,0 
    90 DATA "n",0,65,73,73,73,73,127,0 
    91 DATA "m",0,65,73,73,73,73,127,1 
    92 DATA "e",0,60,66,30,2,66,60,0 
    93 DATA "u",0,76,82,114,82,82,76,0 
    94 DATA "a",0,62,66,66,62,34,66,0 
    95 DATA "s",24,66,70,74,82,98,66,0 
    96 DATA "r",0,64,64,124,66,66,124,0 
    97 DATA "t",0,192,64,124,66,66,124,0 
    98 DATA "f",0,127,73,73,73,127,8,0 
    99 DATA "q",0,66,66,114,74,74,114,0
это частоты? а на сколько часто нужно менять значение частоты?
с вашего позволения я поюзаю значения частот 8)
Top
User avatar
Shaos
Admin
Posts: 24055
Joined: 08 Jan 2003 23:22
Location: Silicon Valley

Post by Shaos »

7400 wrote:

Code: Select all

   80 DATA "b",0,126,64,124,66,66,124,0 
    81 DATA "g",0,126,64,64,64,64,64,0 
    82 DATA "d",0,28,36,36,36,36,126,66 
    83 DATA "j",0,65,73,62,73,73,65,0 
    84 DATA "i",0,66,70,74,82,98,66,0 
    85 DATA "l",0,30,34,34,34,34,98,0 
    86 DATA "p",0,126,66,66,66,66,66,0 
    87 DATA "o",0,66,66,36,24,16,96,0 
    88 DATA "c",0,68,68,68,68,68,126,2 
    89 DATA "h",0,66,66,66,126,2,2,0 
    90 DATA "n",0,65,73,73,73,73,127,0 
    91 DATA "m",0,65,73,73,73,73,127,1 
    92 DATA "e",0,60,66,30,2,66,60,0 
    93 DATA "u",0,76,82,114,82,82,76,0 
    94 DATA "a",0,62,66,66,62,34,66,0 
    95 DATA "s",24,66,70,74,82,98,66,0 
    96 DATA "r",0,64,64,124,66,66,124,0 
    97 DATA "t",0,192,64,124,66,66,124,0 
    98 DATA "f",0,127,73,73,73,127,8,0 
    99 DATA "q",0,66,66,114,74,74,114,0
это частоты? а на сколько часто нужно менять значение частоты?
с вашего позволения я поюзаю значения частот 8)
это буквы :)
русские
точнее их внешний вид
а говорилка сидит в кодовом блоке "ENG-SAY" загружаемом в адрес 60000 и размером 801 байт
Я тут за главного - если что шлите мыло на me собака shaos точка net
Top
7400
Maniac
Posts: 254
Joined: 14 Jul 2011 02:18
Location: Гомель

Post by 7400 »

аа))
типа 8 на 8)ээх)
а не знаете где взять такую таблицу частот чтобы подошли для моего случая?
где-то в книге видел расшифровщик текста методом частотного набора иль что-то подобное но там на букву всего 1 частота и будет гораздо хуже чем у вас

а кстати звук через 1 ножку выводить или всетаки лучше ножек 8 через резисторную обвязку 10-20 ком подключить?

и можете добавить свои 800 байт суда нравится мне этот получаемый звук)
Top
User avatar
Lavr
Supreme God
Posts: 16689
Joined: 21 Oct 2009 08:08
Location: Россия

Post by Lavr »

Shaos wrote:Программа написана на бейсике c русификатором (таким же как и в ZVUK-2) и в ней использовался кодовый блок - говорилка размером меньше килобайта, выдранная мной еще в 1993 году из какой-то восточно-европейской говорящей программы. Английские слова в исполнении этой говорилки звучали вот так: english.mp3 (135K).
Честно говоря, я ни одного слова не разобрал из english.mp3. :(

Там и правда такое неважное качество?
Мой say80 тоже имел металлический акцент, но слова были очень разборчивы!
Или это погрешности создания mp3 со Спектрума (эмулятора)?


PS. Я бы выложил say80, но, к сожалению, старый комп сейчас недоступен.
Но мне кажется, похожие программы можно качнуть здесь: SPEECK_P,
Speaker Mouse, SPP (30529). Они чисто DOS-овские...
Top
User avatar
MC68k
Retired
Posts: 1328
Joined: 25 Jul 2011 00:14
Location: WWW

Post by MC68k »

Lavr wrote: Честно говоря, я ни одного слова не разобрал из english.mp3. :(

Там и правда такое неважное качество?
так надо фонетику вводить, а не письменность. сотоварищ от спектрума более менее вменяемые звуки получал
Top
User avatar
Lavr
Supreme God
Posts: 16689
Joined: 21 Oct 2009 08:08
Location: Россия

Post by Lavr »

MC68k wrote:
Lavr wrote: Честно говоря, я ни одного слова не разобрал из english.mp3. :(

Там и правда такое неважное качество?
так надо фонетику вводить, а не письменность. сотоварищ от спектрума более менее вменяемые звуки получал
А я ничего не вводил. Я послушал, что предложил послушать Шаос, чтобы сравнить.

Я использовал свою говорилку в качестве компьютерного автоответчика.
И он очень разборчиво произносил:
"С Вами говорит автоответчик. Оставьте сообщение после тонального сигнала."
И эта фраза всем понятна была, несмотря на узкую полосу телефонной
линии и металлический акцент.

А в english.mp3 я не опознал ни слова, хотя прослушал из интересу
не один раз.
Top
User avatar
MC68k
Retired
Posts: 1328
Joined: 25 Jul 2011 00:14
Location: WWW

Post by MC68k »

Lavr wrote:
MC68k wrote:
Lavr wrote: Честно говоря, я ни одного слова не разобрал из english.mp3. :(

Там и правда такое неважное качество?
так надо фонетику вводить, а не письменность. сотоварищ от спектрума более менее вменяемые звуки получал
А я ничего не вводил. Я послушал, что предложил послушать Шаос, чтобы сравнить.

Я использовал свою говорилку в качестве компьютерного автоответчика.
И он очень разборчиво произносил:
"С Вами говорит автоответчик. Оставьте сообщение после тонального сигнала."
И эта фраза всем понятна была, несмотря на узкую полосу телефонной
линии и металлический акцент.

А в english.mp3 я не опознал ни слова, хотя прослушал из интересу
не один раз.
дык я в общем. кто вводил тому пусть будет ай-яй-яй.
послушал один раз. лучше бы я этого не делал.
разобрал два слова амазон и инструмент.
Top
User avatar
Shaos
Admin
Posts: 24055
Joined: 08 Jan 2003 23:22
Location: Silicon Valley

Post by Shaos »

MC68k wrote:
Lavr wrote:
MC68k wrote:
Lavr wrote: Честно говоря, я ни одного слова не разобрал из english.mp3. :(

Там и правда такое неважное качество?
так надо фонетику вводить, а не письменность. сотоварищ от спектрума более менее вменяемые звуки получал
А я ничего не вводил. Я послушал, что предложил послушать Шаос, чтобы сравнить.

Я использовал свою говорилку в качестве компьютерного автоответчика.
И он очень разборчиво произносил:
"С Вами говорит автоответчик. Оставьте сообщение после тонального сигнала."
И эта фраза всем понятна была, несмотря на узкую полосу телефонной
линии и металлический акцент.

А в english.mp3 я не опознал ни слова, хотя прослушал из интересу
не один раз.
дык я в общем. кто вводил тому пусть будет ай-яй-яй.
послушал один раз. лучше бы я этого не делал.
разобрал два слова амазон и инструмент.
это был не "амазон", а "commercial" ;)
вот список проговоренного - в говорилку ходило последнее слово в строке (типа транскрипция):

Code: Select all

 5001 DATA "3A\pAC C\lOB","VOCABULARY","VEKEEB'ULERI"
 5002 DATA "CM\qC\l","MEANING","MIINING"
 5003 DATA "\dOKA3\qBAT\r","PROVE","PRUUUV"
 5004 DATA "\dO\gOBOP\iT\rC\a","AGREE UPON","EGRII EPOON"
 5005 DATA "\fAKT\i\hECK\i\s","ACTUAL","EEKT'UEL"
 5006 DATA "TO\hH\q\s","ACCURATE","EEK'URIT"
 5007 DATA "\pPOM\q\n\lEHH\q\s","COMMERCIAL","KEMEESEL"
 5008 DATA "\dAHH\qE","DATA","DEEITE"
 5009 DATA "\f\i\g\oPA","FIGURE","FIIGE"
 5010 DATA "\pP\i\bOP","INSTRUMENT","IINSTRUMENT"
 5011 DATA "C\o\mECTBEHH\q\s","MATERIAL","METIIRIEL"
 5012 DATA "\g\lABH\q\s","PRINCIPAL","PRIINSIPEL"
 5013 DATA "\pOCTE\pEHH\q\s","PROGRESSIVE","PREGREESIV"
 5014 DATA "\cE\l\r","OBJECT","OOBZIKT"
 5015 DATA "O\b\tEKT","SUBJECT","SAABZIKT"
 5016 DATA "O\hEH\r","GREATLY","GREEITLI"
 5017 DATA "\n\iPOKO","LARGELY","LAAZHLI"
 5018 DATA "E\dBA","HARDLY","HAADLI"
 5019 DATA "\pO\hT\i","NEARLY","NIIELI"
 5020 DATA "\p\lOXO","POORLY","PUUELI"
 5021 DATA "\pOKA","SO FAR","SOU FAA"
 5022 DATA "\lE\gKO","READILY","REEDILI"
Я тут за главного - если что шлите мыло на me собака shaos точка net
Top
User avatar
MC68k
Retired
Posts: 1328
Joined: 25 Jul 2011 00:14
Location: WWW

Post by MC68k »

ЕМНИП звучание лучше было
Top
User avatar
Shaos
Admin
Posts: 24055
Joined: 08 Jan 2003 23:22
Location: Silicon Valley

Post by Shaos »

MC68k wrote:ЕМНИП звучание лучше было
Ну дык во времена нашей юности и деревья были больше, и воздух чище, и народ добрее...
Я тут за главного - если что шлите мыло на me собака shaos точка net
Top
User avatar
Lavr
Supreme God
Posts: 16689
Joined: 21 Oct 2009 08:08
Location: Россия

Post by Lavr »

Shaos wrote:
MC68k wrote:ЕМНИП звучание лучше было
Ну дык во времена нашей юности и деревья были больше, и воздух чище, и народ добрее...
Да-да... помню-помню... мне об этом часто напоминают, что и трава зеленее!!! :o
И даже сопли... хм... качественнее что-ли были... :lol:
Top
User avatar
Shaos
Admin
Posts: 24055
Joined: 08 Jan 2003 23:22
Location: Silicon Valley

Post by Shaos »

Обнаружил мою фотку своего ленинграда "Урал" на спекивике:

http://speccy.info/%D0%A3%D1%80%D0%B0%D0%BB-48%D0%9A

Чуваки даже не удосужились написать, что на этом конкретной девайсе клава перепаяна с резиновой на настоящую :)
Я тут за главного - если что шлите мыло на me собака shaos точка net
Top

Return to “ZX Spectrum (RUS)”