Старье от Шаоса

Shaos · Post by **Shaos** » 20 Jun 2016 14:57

Black_Cat wrote:
Shaos wrote:
Black_Cat wrote:
Shaos wrote:
Black_Cat wrote:УОМЗ вроде Кворумы производил.
Урал был до Кворума
Ты же говорил, что это был Ленинград.
Ты же сам сказал, что это Балтик...
Это - да, Балтик, но я не знаю что у тебя было в детстве, а ты говорил, что Ленинград, или ты это думал что Ленинград, а насамделе был Балтик? У всех Балтиков, из-за 16МГц экран квадратный, такое невозможно не заметить.
Неправильные данные про Ленинград на сценерской вики, тож от тебя?

Ну дык оно и было (правда не в детстве - скорее в юности ; )
А как выглядит Ленинград я узнал только будучи в Америке

P.S. На той вике я поправил что мог (статья не моя) - и к своей фотке (что автор статьи прицепил изначально) объяснялку написал, что клава не родная http://speccy.info/%D0%A3%D1%80%D0%B0%D0%BB-48%D0%9A
http://speccy.info/%D0%9E%D0%B1%D1%81%D1%83%D0%B6%D0%B4%D0%B5%D0%BD%D0%B8%D0%B5:%D0%A3%D1%80%D0%B0%D0%BB-48%D0%9A

Black_Cat · Post by **Black_Cat** » 20 Jun 2016 16:03

А в каком году этот Урал у тебя был?

Shaos · Post by **Shaos** » 20 Jun 2016 17:50

Black_Cat wrote:А в каком году этот Урал у тебя был?

с осени 1992 по весну 2004, но последний раз я его включал наверное в 1998, когда писал свою ось ShaOS, а в 2002 у меня появился Спринтер - из спектрумов я только его в США забрал...

Shaos · Post by **Shaos** » 10 Jul 2016 13:28

Shaos wrote:Обнаружил у себя ещё один видеодевайс, который умеет PAL - видео очки ezVision

о - маленький китайский телек LCD тоже умеет чёрно-белый PAL/SECAM

P.S. а вообще да - я же его ради мультисистемности и покупал

Shaos · Post by **Shaos** » 10 Sep 2016 20:29

Shaos wrote:
Black_Cat wrote:А в каком году этот Урал у тебя был?
с осени 1992 по весну 2004, но последний раз я его включал наверное в 1998, когда писал свою ось ShaOS, а в 2002 у меня появился Спринтер - из спектрумов я только его в США забрал...

Нашел фотку примерно 1993 года где клава еще родная - это в нашей общаге РТФ УПИ:

Shaos · Post by **Shaos** » 10 Sep 2016 20:36

Фотка уже пролетала на нашем форуме в 2010 году

viewtopic.php?p=85352#p85352

jdigreze · Post by **jdigreze** » 11 Sep 2016 00:46

А у меня такой же магнитофон был к спектруму, пока у него лентопротяжный не сдох.

Shaos · Post by **Shaos** » 30 Sep 2016 12:06

Shaos wrote:Фотка уже пролетала на нашем форуме в 2010 году
viewtopic.php?p=85352#p85352

Обновил мессагу с фотками моих спектрозверей, добавив туда вышеприведённую фотку, а также только-что обнаруженную фотку Пентагона снятую в августе 2001 (судя по цифрам на фотке):

viewtopic.php?p=105262#p105262

Shaos · Post by **Shaos** » 22 Oct 2016 20:04

Shaos wrote:Решил восстановить тексты программ из TAP-файлов с помощью утилиты listbasic из fuse-utils

Shaos wrote:Одна из первых программ,
которые я набрал и потом слегка модифицировал - это бейсик-программа
для ввода машинных кодов из мини-книжки от Солона под незатейливым
названием "Ассемблер для ПК ZX SPECTRUM" (которую я кстати взял с
собой в США). Прогрмма находится в архиве под названием _hexloa2.tap:

Code: Select all

  100 REM MONITOR PROGRAM
  110 DIM z(4): LET z(1)=4096: LET z(2)=256: LET z(3)=16: LET z(4)=1
  120 LET ze=0: LET on=1: LET tw=2
  121 LET qk=256: LET mr=140
  122 LET wl=340
  123 LET l$="6C00"
  125 LET n$=l$: GO SUB 3000: LET lm=d
  130 GO SUB 2000
  140 CLS : PAPER 3: INK 7: PRINT "HEXLOAD-2 1982,1992  Shabarshin "
  145 PAPER 7: INK 0: PRINT "Start of,machin code area=";l$
  150 PRINT "MENU": PRINT : PRINT "     Write machin code.........1"
  160 PRINT : PRINT "     Save  machin code.........2"
  170 PRINT : PRINT "     Load  machin code.........3"
  180 PRINT : PRINT "     List  machin code.........4"
  190 PRINT : PRINT "     Move  machin code.........5"
  195 PRINT : PRINT "     Work  of  program.........6"
  200 PRINT : PRINT "Please press appropriate key. "
  210 LET g$=INKEY$
  220 IF g$=" " THEN STOP 
  230 IF g$="" OR g$<"1" OR g$>"6" THEN GO TO 210
  240 CLS : PRINT "Start of machin code area=";l$
  250 GO TO 300*VAL g$
  300 REM ***WRITE***
  310 INPUT "WRITE to address:";n$: GO SUB 3000
  320 IF d>mm OR d<lm THEN BEEP 1,10: GO TO 310
  325 PRINT : PRINT "to RETURN to!MENU ENTER""m"""
  330 INK 2: PRINT "WRITE address:";n$
  331 PAPER 6: PRINT "0 1 2 3 4 5 6 7 8 9 A B C D E F ": PAPER 7: INK 0
  335 LET c=32*(d/16-INT (d/16)): PRINT AT 5,c;
  340 LET a$=""
  350 IF a$="" THEN INPUT "ENTER hex. CODE: ";a$
  360 IF a$(on)=" " OR a$(on)="m" THEN GO TO mr
  370 IF LEN a$/tw<>INT (LEN a$/tw) THEN BEEP 1,10: GO TO wl
  380 LET c=ze
  390 FOR f=16 TO on STEP -15
  400 LET a=CODE a$((f=16)+tw*(f=on))
  410 IF a<48 OR a>102 OR (a>57 AND a<65) OR (a>70 AND a<97) THEN BEEP 1,10: GO TO wl
  420 LET c=c+f*((a<58)*(a-48)+(a>64 AND a<71)*(a-55)+(a>96)*(a-87))
  430 NEXT f: POKE d,c: LET d=d+on
  440 PAPER 7-2*(d/2-INT (d/2)): PRINT a$;: PAPER 7
  450 LET a$=a$(3 TO )
  460 IF d=UDG THEN PRINT "WARNING:YOU ARE NOW IN the USER GRAPHICS AREA!": BEEP 1,0: GO TO wl
  470 IF d=UDG-20 THEN PRINT "WARNING:YOU ARE NOW IN ROUTINES MEMORY AREA!": BEEP 1,0: GO TO wl
  480 GO TO wl+on
  600 REM ***SAVE***
  610 INPUT "SAVE m/C. FROM ADDRESS: ",n$: GO SUB 3000: LET a=d
  620 INPUT "NUMBER OF BYTES to be SAVED: ",n
  630 INPUT "NAME OF the ROUTINE: ";a$
  640 SAVE a$CODE a,n
  650 PRINT "DO YOU WISH to VERITY?"
  660 INPUT v$
  670 IF v$<>"y" THEN GO TO mr
  680 PRINT "REWIND tape AND PRESS""PLAY""."
  690 VERIFY a$CODE a,n
  700 PRINT "O.K. ": PAUSE 50
  710 GO TO mr
  900 REM ***LOAD***
  910 INPUT "LOAD m.C. TO ADDRESS STARTING: ";n$: GO SUB 3000: LET a=d
  920 IF a>mm OR a<lm THEN GO TO 910
  930 INPUT "Program NAME: ";a$
  940 PRINT "Press ""PLAY"" ON tape. "
  950 LOAD a$CODE : GO TO mr
 1200 REM ***LIST***
 1210 LET a$="0123456789ABCDEF"
 1220 INPUT "LIST ADDRESS: ";n$: GO SUB 3000
 1230 PRINT "Press ""m"" to RETURN to MENU. "
 1240 LET c=PEEK d: LET a=INT (c/16): LET b=c-16*a
 1241 LET a1=INT (d/4096): LET a2=INT ((d-a1*4096)/356)
 1242 LET a3=INT ((d-a1*4096-a2*256)/16): LET a4=d-a1*4096-a2*256-a3*16
 1245 LET q$="": LET co=PEEK d: IF co>31 AND co<165 THEN LET q$=CHR$ co
 1250 PRINT a$(a1+on);a$(a2+on);a$(a3+on);a$(a4+on);"  ";a$(a+on);a$(b+on);"   ";q$
 1260 LET d=d+on
 1270 IF INKEY$="m" THEN GO TO mr
 1280 GO TO 1240
 1500 REM ***MOVE***
 1510 INPUT "MOVE from memory: ";n$: GO SUB 3000: LET fm=d
 1520 INPUT "MOVE until memory: ";n$: GO SUB 3000: LET um=d
 1530 INPUT "MOVE to memory: ";n$: GO SUB 3000: LET tm=d
 1540 IF tm>fm THEN GO TO 1610
 1550 LET mo=tm
 1560 FOR i=fm TO um
 1570 POKE mp,PEEK i
 1580 LET mp=mp+on
 1590 NEXT i
 1600 GO TO mr
 1610 LET mp=um+tm-fm
 1620 FOR i=um TO fm STEP -on
 1630 POKE mp,PEEK i
 1640 LET mp=mp-on
 1650 NEXT i
 1660 GO TO mr
 1800 REM ***WORK***
 1810 INPUT "Address of start: ";n$: GO SUB 3000: CLS 
 1820 RANDOMIZE USR d: GO TO mr
 2000 LET rt=PEEK 23732+qk*PEEK 23733
 2010 IF rt=65535 THEN LET mm=65347: LET UDG=65367
 2020 IF rt=32777 THEN LET mm=32579: LET UDG=32599
 2030 LET n1=INT (UDG/qk)
 2040 POKE 23675,UDG-n1*qk: POKE 23676,n1
 2050 RETURN 
 3000 REM sub***TRANS***
 3005 IF LEN n$<>4 THEN GO TO mr
 3010 LET d=ze: FOR i=1 TO 4: LET a=CODE n$(i)
 3020 IF a<48 OR a>102 OR (a>57 AND a<65) OR (a>70 AND a<97) THEN GO TO mr
 3030 LET d=d+z(i)*((a<58)*(a-48)+(a>64 AND a<71)*(a-55)+(a>96)*(a-87))
 3040 NEXT i: RETURN

P.S. Как я уже писал выше, я взял эту бейсик-программу (и слегка модифицировал) из мини-книжки от Солона под незатейливым названием "Ассемблер для ПК ZX SPECTRUM":

Наконец-то ко мне в руки попала книжка 1982 года, из которой издательство Солон всё и скопировала

Старье от Шаоса

Re: Старье от Шаоса

Re: Старье от Шаоса

Re: Старье от Шаоса

Re: Старье от Шаоса

Re: Старье от Шаоса

Re: Старье от Шаоса

Re: Старье от Шаоса

Re: Старье от Шаоса

Re: Старье от Шаоса